VB.NET: Recuperare in maniera automatica il nome della proprietà in cui si ci trova

La semplice classe che vi propongo permette di ricavare, sfruttando lo stacktrace, il nome della proprietà in cui ci si trova dinamicamente.

La classe è una classe utility che presenta un metodo statico il cui risultato è il nome della property in cui ci si trova (sia che siamo nel Get che nel Set) oppure Nothing se non siamo in una property:

1. Public NotInheritable Class PropertyHelper
2.     Private Sub New()
3.  
4.     End Sub
5.  
6.     Private Const SetPropertyPrefix = "set_"
7.     Private Const GetPropertyPrefix = "get_"
8.  
9.     Public Shared Function GetCurrentPropertyName() As String
10.         Dim retval As String = Nothing
11.         Dim method = (From sf In New StackTrace().GetFrames
12.                     Where sf.GetMethod().DeclaringType <> GetType(PropertyHelper)
13.                     Select sf.GetMethod()).FirstOrDefault()
14.         If method IsNot Nothing Then
15.             If method.Name.StartsWith(SetPropertyPrefix) Then
16.                 retval = method.Name.Replace(SetPropertyPrefix, "")
17.             End If
18.             If method.Name.StartsWith(GetPropertyPrefix) Then
19.                 retval = method.Name.Replace(GetPropertyPrefix, "")
20.             End If
21.         End If
22.         Return retval
23.     End Function
24. End Class

La classe può essere utilizzata, ad esempio, nelle proprietà di quelle classi che implementano l’interfaccia INotifyPropertyChanged per non “cablare” la stringa con il nome delle proprietà all’interno del codice:

1. Imports System.ComponentModel
2.  
3. Public Class Utente
4.     Implements INotifyPropertyChanged
5.  
6.     Private _Nome As String
7.     Public Property Nome() As String
8.         Get
9.             Return _Nome
10.         End Get
11.         Set(ByVal value As String)
12.             If value <> _Nome Then
13.                 _Nome = value
14.                 OnPropertyChanged(PropertyHelper.GetCurrentPropertyName())
15.             End If
16.         End Set
17.     End Property
18.  
19.     Protected Sub OnPropertyChanged(ByVal propertyName As String)
20.         RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName))
21.     End Sub
22.  
23.     Public Event PropertyChanged(ByVal sender As Object,
24.                                  ByVal e As System.ComponentModel.PropertyChangedEventArgs) _
25.                              Implements System.ComponentModel.INotifyPropertyChanged.PropertyChanged
26. End Class

 

Technorati Tag: StackTrace,Reflection,diagnostic,property,inotifypropertychanged,inotifypropertychanging