Definire i contratti su interfacce generiche in VB.NET

Uno dei grandi vantaggi dei code contracts di Microsoft (vedere gli articoli sul sito www.domusdotnet.org per maggiori info) è quello di poter definire i contratti anche sulle interfacce.

Ad esempio le precondizioni si definiscono attraverso uno dei metodi statici Requires della classe Contracts (System.Diagnostic.Contracts):

1. Imports System.Diagnostics.Contracts
2.  
3. Module Module1
4.  
5.     Sub Main()
6.         Dim chr = GetLastChar("pippo")
7.         Dim chr2 = GetLastChar("")
8.     End Sub
9.  
10.     Public Function GetLastChar(str As String) As String
11.         Contract.Requires(Not String.IsNullOrEmpty(str))
12.         Return str.Substring(str.Length - 1)
13.     End Function
14.  
15. End Module

Il metodo GetLastChar richiede che l’argomento non sia né Nothing, né “” e, nel caso precedente, in fase di compilazione, si ottiene il seguente warning

mentre in fase di esecuzione si ottiene la seguente eccezione:

Fino a qui tutto bene, ma come facciamo a definire le precondizioni (ma il concetto vale anche per postcondizioni ed invarianti d’oggetto) nel caso di interfacce o di metodi astratti di classi in cui non abbiamo la possibilità di inserire del codice?

In questo caso abbiamo la possibilità di definire una classe che funge da “contenitore” per le definizioni dei contratti. Ad esempio:

1. <ContractClass(GetType(InterfacciaContract))>
2. Public Interface IInterfaccia
3.     Function Metodo(arg As Integer) As Integer
4. End Interface
5.  
6. <ContractClassFor(GetType(IInterfaccia))>
7. Public MustInherit Class InterfacciaContract
8.     Implements IInterfaccia
9.  
10.     Public Function Metodo(arg As Integer) As Integer Implements IInterfaccia.Metodo
11.         Contract.Requires(arg > 0)
12.         Throw New NotSupportedException
13.     End Function
14. End Class

La classe InterfacciaContract funge da contenitore per i contratti dei metodi esposti dalla Interfaccia.

Il codice presente nei metodi dell’interfaccia implementati dalla classe contenitore non viene eseguito se non quello relativo alla definizione dei contratti.

Il problema nasce quando abbiamo una interfaccia generica (ovvero il cui comportamento dipende da uno o più tipi). In questo caso come definiamo la classe “contenitore” dei contratti e come indichiamo il tipo dell’interfaccia nell’attributo ContractClassFor?

In questo caso si può utilizzare la sintassi NomeTipo(Of ) come mostrato nel seguente esempio:

1. <ContractClass(GetType(RepositoryContract(Of )))>
2. Public Interface IRepository(Of T)
3.     Function GetAll() As IEnumerable(Of T)
4.     Function GetSingle(id As Integer) As IEnumerable(Of T)
5. End Interface
6.  
7. <ContractClassFor(GetType(IRepository(Of )))>
8. Public MustInherit Class RepositoryContract(Of T)
9.     Implements IRepository(Of T)
10.  
11.     Public Function GetSingle(id As Integer) As System.Collections.Generic.IEnumerable(Of T) Implements IRepository(Of T).GetSingle
12.         Contract.Requires(id > 0)
13.         Throw New NotImplementedException()
14.     End Function
15.  
16.     Public Function GetAll() As System.Collections.Generic.IEnumerable(Of T) Implements IRepository(Of T).GetAll
17.         Throw New NotImplementedException()
18.     End Function
19. End Class

Nel momento in cui definiamo una classe reale imponendo il tipo T, avremo che il contratto viene “ereditato” automaticamente:

1. Public Class Repository
2.     Implements IRepository(Of Entity)
3.  
4.     Public Function GetSingle(id As Integer) As System.Collections.Generic.IEnumerable(Of Entity) Implements IRepository(Of Entity).GetSingle
5.         Return Nothing
6.     End Function
7.  
8.     Public Function GetAll() As System.Collections.Generic.IEnumerable(Of Entity) Implements IRepository(Of Entity).GetAll
9.         Return Nothing
10.     End Function
11. End Class

senza che noi si debba riscriverlo.

Nel caso in cui l’interfaccia dipenda da più tipi è sufficiente scrivere le opportune virgole:

1. <ContractClass(GetType(RepositoryContract(Of ,)))>
2. Public Interface IRepository(Of T1, T2)
3.     Function GetAll() As IEnumerable(Of T1)
4.     Function GetSingle(id As Integer) As IEnumerable(Of T1)
5. End Interface
6.  
7. <ContractClassFor(GetType(IRepository(Of ,)))>
8. Public MustInherit Class RepositoryContract(Of T1, T2)
9.     Implements IRepository(Of T1, T2)
10.  
11.     Public Function GetAll() As System.Collections.Generic.IEnumerable(Of T1) Implements IRepository(Of T1, T2).GetAll
12.         Throw New NotImplementedException()
13.     End Function
14.  
15.     Public Function GetSingle(id As Integer) As System.Collections.Generic.IEnumerable(Of T1) Implements IRepository(Of T1, T2).GetSingle
16.         Contract.Requires(id > 0)
17.         Throw New NotImplementedException()
18.     End Function
19. End Class

 

Tag di Technorati: code contracts,interfacce,abstract class,generics