Passa ai contenuti principali

VB.NET: Convertire un file DOC in RTF e PDF con office interop

In questo post vorrei proporvi del codice per poter convertire un file .doc in un file .rtf oppure .pdf utilizzando le API di interoperabilità di Office.

Creeremo una classe, DocConverter, che esporrà le due funzionalità sopra citate.

Cominciamo con il prevedere un attributo privato della classe che rappresenterà l’applicazione Word che utilizzeremo per la conversione. Creeremo l’istanza dell’attributo privato all’interno del costruttore della classe:

Public Sub New() 
    If Not CreateWordApp() Then 
        Throw New ApplicationException("Assembly di interoperabilità con Office non trovato!") 
    End If 
End Sub 
Private _wordApp As Word.ApplicationClass 
Protected Function CreateWordApp() As Boolean 
    Dim retval = True 
    Try 
        _wordApp = New Word.ApplicationClass() 
        _wordApp.Visible = False 
    Catch ex As System.Exception 
        _wordApp = Nothing 
        retval = False 
    End Try 
    Return retval 
End Function


La conversione del file doc sarà effettuata aprendo il file stesso ed eseguendo un’operazione di SaveAs:



Private Function OpenDocument(ByVal oFileName As Object) As Word.Document 
    Dim missing As Object = System.Reflection.Missing.Value 
    Dim aDoc As Word.Document = Nothing 
    Try 
        aDoc = _wordApp.Documents.Open(oFileName, missing, False, _ 
                                       missing, missing, missing, _ 
                                       missing, missing, missing, _ 
                                       missing, missing, False) 
    Catch ex As System.Exception 
        aDoc = Nothing 
    End Try 
    Return aDoc 
End Function
Private Function SaveDocumentAs(ByVal document As Word.Document, _ 
                                ByRef filename As String, _ 
                                ByVal wdSaveFormat As Integer) As DocConverterResult 
    Dim retval As DocConverterResult = DocConverterResult.OK 
    Try 
        document.SaveAs(CType(filename, Object), CType(wdSaveFormat, Object)) 
    Catch ex As System.Exception 
        retval = DocConverterResult.DestinationFileNotCreate 
    Finally 
        document.Close() 
    End Try 
    If Not File.Exists(filename.ToString()) Then 
        retval = DocConverterResult.DestinationFileNotCreate 
        filename = "" 
    End If 
    Return retval 
End Function


A questo punto, implementata la funzionalità di SaveAs, ci basta implementare i due metodi richiamabili dall’esterno per la conversione:



Public Function ConvertToRTF(ByVal fileName As String, _
                             ByRef rtfFileName As String, _
                             Optional ByVal destinationPath As String = "") As DocConverterResult
    Dim retval As DocConverterResult = DocConverterResult.OK
    If _wordApp IsNot Nothing Then
        Dim oFileName As Object = fileName
        Dim aDoc As Word.Document = OpenDocument(oFileName)
        If aDoc IsNot Nothing Then
            If Not String.IsNullOrEmpty(destinationPath) Then
                Dim finfo = New FileInfo(fileName)
                rtfFileName = Path.Combine(destinationPath, finfo.Name.ToLower().Replace(".doc", ".rtf"))
            Else
                rtfFileName = fileName.ToLower().Replace(".doc", ".rtf")
            End If
            retval = SaveDocumentAs(aDoc, rtfFileName, Word.WdSaveFormat.wdFormatRTF)
        End If
    Else
        retval = DocConverterResult.OfficeComponentNotFound
    End If
    Return retval
End Function
Public Function ConvertToPDF(ByVal fileName As String, _
                             ByRef pdfFileName As String, _
                             Optional ByVal destinationPath As String = "") As DocConverterResult
    Dim retval As DocConverterResult = DocConverterResult.OK
    If _wordApp IsNot Nothing Then
        Dim oFileName As Object = fileName
        Dim aDoc As Word.Document = OpenDocument(oFileName)
        If aDoc IsNot Nothing Then
            If Not String.IsNullOrEmpty(destinationPath) Then
                Dim finfo = New FileInfo(fileName)
                pdfFileName = Path.Combine(destinationPath, finfo.Name.ToLower().Replace(".doc", ".pdf"))
            Else
                pdfFileName = fileName.ToLower().Replace(".doc", ".pdf")
            End If
            retval = SaveDocumentAs(aDoc, pdfFileName, wdFormatPDF)
        End If
    Else
        retval = DocConverterResult.OfficeComponentNotFound
    End If
    Return retval
End Function


La classe DocConverter, infine, implementa l’interfaccia IDisposable in modo da poter, nell’evento Dispose(), rilasciare in maniera corretta l’applicazione Word (che compare all’interno del task manager durante lo scope di esecuzione dell’istanza della classe).



Per poter utilizzare l’oggetto Word.ApplicationClass è necessario referenziare la dll Microsoft.Office.Interop.Word.dll (un’istalllazione di Word contiene tale dll) mentre per abilitare il salvataggio in PDF è necessario scaricare il plug-in per office scaricabile dall’indirizzo:



http://www.microsoft.com/downloads/details.aspx?FamilyID=f1fc413c-6d89-4f15-991b-63b07ba5f2e5&DisplayLang=en



Il plug-in funziona su Office 2007.



Un progetto demo con la classe è scaricabile cliccando sulla seguente icona:




 




Commenti

Post popolari in questo blog

VB.NET : Aggregare stringhe con LINQ

Tip facile facile, ma a qualcuno potrebbe servire. Supponiamo di avere una lista di stringhe (magari come risultato di una query LINQ) e di voler ottenere una stringa con la concatenazione delle stesse: Dim list = CreateList() Dim concatStr = (From s In list _ Select s).Aggregate( Function (currentString, nextString) currentString + nextString) MessageBox.Show(concatStr) Il metodo CreateList non ci interessa, in questo momento, ma crea una lista di oggetti String. Protected Function CreateList() As IEnumerable( Of String ) Dim list As String () = {" stringa1 ", " stringa2 ", " stringa3 ", " stringa4 ", " stringa5 "} Return list.AsEnumerable() End Function Questo metodo potrebbe restituire una qualsiasi lista di oggetti di cui, nella select successiva recuperiamo solo stringhe. La stessa tecnica è utilizzabile per concatenare stringhe inserendovi un carattere separatore Dim list = CreateList() Dim

VB.NET: SplashScreen con effetto fade-in

In questo post vorrei proporvi un modo per realizzare una splash screen per le nostre applicazioni Windows Form che appare progressivamente con un effetto fade. Supponiamo di avere il nostro progetto VB.NET in una soluzione Visual Studio 2008 in cui abbiamo il sorgente della nostra applicazione Windows Form. Inseriamo una splash screen utilizzando il menù Progetto->Aggiungi Nuovo Elemento e selezionando il tipo di elemento “Schermata Iniziale” A questo punto Visual Studio creerà, automaticamente, la schermata iniziale che possiamo personalizzare graficamente come vogliamo. Per poter fare in modo che questa finestra appaia nel momento in cui avviamo l’applicazione, è necessario aprire le proprietà del progetto e impostare la maschera di avvio: In questo modo, all’avvio dell’applicazione, la schermata appare immediatamente e scompare un attimo prima della visualizzazione della finestra dell’applicazione. Possiamo far apparire la schermata iniziale con un ef