Nel precedente post di questa serie abbiamo visto cosa sono gli eventi. In questo post vedremo, invece, una specie particolare di eventi denominati “eventi custom”.
Cosa sono
Gli eventi custom sono a tutti gli effetti degli eventi ma danno la libertà allo sviluppatore di gestire tutte le fasi di vita degli stessi, cioè permettono di gestire:
- Aggancio degli handler;
- Rimozione degli handler;
- Esecuzione dell’evento.
Negli eventi standard (come abbiamo visto anche nel precedente post della serie) la gestione della lista dei delegate agganciati all’evento (aggiunta di un nuovo delegate, rimozione di un delegarte e invocazione dell’evento) sono a carico del compilatore e non dobbiamo preoccuparci di nulla.
Come si definiscono
Definire un evento custom è relativamente semplice, basta utilizzare la parola chiave Custom:
- Public Custom Event CustomEvent As MyDelegate
- AddHandler(ByVal value As MyDelegate)
- End AddHandler
- RemoveHandler(ByVal value As MyDelegate)
- End RemoveHandler
- RaiseEvent()
- End RaiseEvent
- End Event
I custom event possono essere definiti solo urilizzando un delegate, quindi, dobbiamo definire la firma del nostro evento custom creando un delegate pubblico.
Come possiamo vedere dal precedente codice, il corpo del nostro custom event è formato da tre distinte sezioni:
- AddHandler : è la sezione che si occupa di gestire l’accodamento di un nuovo gestore di evento. Questa sezione viene richiamata ogni qual volta che, nel codice, ci sia un’istruzione AddHandler riferita all’evento;
- RemoveHandler: è la sezione che si occupa di gestire lo scodamento di un gestore di evento. Questa sezione viene richiamata ogni volta che, nel codice, ci sia un’istruzione RemoveHandler;
- RaiseEvent: è la sezione che si occupa dell’invocazione dell’evento. Questa sezione viene richiamata ogni volta che, nel codice, viene eseguita un’istruzione RaiseEvent relativa all’evento.
Quando utilizzarli
Considerato il fatto che dobbiamo gestire noi la lista dei gestori di evento agganciati al nostro evento (lo possiamo fare utilizzando un MultiCastDelegate) e preoccuparci di invocare ognuno di questi nel momento in cui facciamo RaiseEvent, gli eventi custom sono da utilizzare solo quando veramente non possiamo farne a meno e, in particolare, quando vogliamo avere pieno controllo su tutte le fasi degli stessi.
Un esempio pratico
Per dare un esempio di come implementare un custom event supponiamo di voler relizzare una classe che disponga di un evento la cui modalità di invocazione sia costruita in modo da lanciare i gestori di evento associati in parallelo.
Normalmente, gli eventi standard eseguono i gestori di evento in maniera sequenziale a partire dal primo che è stato aggiunto tramite la parola chiave AddHandler.
Cominciamo definendo il delegate che rappresenta la firma del nostro evento:
- Public Delegate Sub MioEventoDelegate(ByVal str As String, ByVal datetime As DateTime)
Il delegate non ha, ovviamente, traccia del fatto che verrà utilizzato in un evento custom o in uno standard (e per far vedere questo la nostra classe conterrà anche un evento standard).
A questo punto definiamo l’evento custom con le strutture dati necessarie per gestire la lista dei gestori di evento:
- Private _EventoParalleloStore As MioEventoDelegate
- Public Custom Event EventoParallelo As MioEventoDelegate
- AddHandler(ByVal value As MioEventoDelegate)
- If value Is Nothing Then Throw New ArgumentNullException()
- Me._EventoParalleloStore = DirectCast([Delegate].Combine(Me._EventoParalleloStore, value), MioEventoDelegate)
- End AddHandler
- RemoveHandler(ByVal value As MioEventoDelegate)
- If value Is Nothing Then Throw New ArgumentNullException()
- Me._EventoParalleloStore = DirectCast([Delegate].Remove(Me._EventoParalleloStore, value), MioEventoDelegate)
- End RemoveHandler
- RaiseEvent(ByVal str As String, ByVal datetime As DateTime)
- If _EventoParalleloStore IsNot Nothing Then
- For Each e In _EventoParalleloStore.GetInvocationList()
- Dim thread = New Threading.Thread(AddressOf RaiseEventoParalleloThread)
- thread.Start(New ThreadParameter() With {.Delegate = e,
- .DateTime = datetime,
- .Str = str})
- Next
- End If
- End RaiseEvent
- End Event
L’attributo privato _EventoParalleloStore si occupa di memorizzare la lista di gestori di evento associati all’evento. Di fatto si tratta di un MultiCastDelegate.
L’aggiunta di un gestore di evento (AddHandler) avviene utilizzando la funzione Combine tra _EventoParalleloStore e il delegate passato per argomento (value).
In maniera analoga utilizziamo il Remove della classe Delegate per rimuovere il gestore di evento.
La parte più interessante, è, infine, quella che si occupa di eseguire, in maniera parallela, i gestori di evento (RaiseEvent). In questo caso eseguiamo un ciclo su tutti i gestori presenti nella lista e, per ognuno di questi, lanciamo un thread che esegue la seguente funzione:
- Private Sub RaiseEventoParalleloThread(ByVal obj As Object)
- Dim param = CType(obj, ThreadParameter)
- param.Delegate.DynamicInvoke(param.Str, param.DateTime)
- End Sub
Per eseguire il gestore di evento (che lo ricordiamo è, alla fine dei conti, un delegate) è sufficiente richiamare il metodo DynamicInvoke.
Il risultato definitivo è che, quando nel codice della classe scriviamo:
- RaiseEvent EventoParallelo(str, DateTime.Now)
otteniamo che i gestori dell’avento eventualmente associati vengono richiamati su thread differenti in maniera parallela.
In allegato potete trovare la solution completa per Visual Studio 2010. In questa troverete una modifica relativa alla parte di invocazione dei gestori di evento in cui si utilizzano i Task.
Commenti