System.Numerics.Complex, finalmente risolviamo le equazioni di secondo grado!!!

Vorrei segnalarvi che nella versione 4.0 del framework è stato introdotto un nuovo namespace, chiamato System.Numerics, contenente dei tipi numerici che fino ad ora mancavano all’interno del framework: i numeri complessi e gli interi di dimensione non definita.

In questo post ci occupiamo dei numeri complessi.

Prima di vedere come sono implementati nel framework, vorrei richiamare alcuni concetti matematici.

I numeri complessi sono un'estensione dei numeri reali nata inizialmente per consentire di trovare tutte le soluzioni delle equazioni polinomiali. Ad esempio, l'equazione

non ha soluzioni reali, perché in questo insieme non esistono numeri il cui quadrato sia negativo.

Si definisce allora il valore i, chiamato anche unità immaginaria, che gode della seguente proprietà:

e dunque:

I numeri complessi sono formati da due parti, una parte reale ed una parte immaginaria, e sono rappresentati dalla seguente espressione:

dove a e b sono numeri reali, mentre i è l'unità immaginaria.

Per maggiori info di carattere matematico http://it.wikipedia.org/wiki/Numero_complesso

Il framework implementa i numeri complessi tramite la  struttura Complex.

La struttura mette a disposizione 4 proprietà:

• Imaginary : è un double che contiene la parte immaginaria del numero complesso;
• Magnitude : è il raggio del numero complesso rappresentato in forma polare;
• Phase : è l’angolo del numero complesso rappresentato in forma polare;
• Real : è un double che contiene la parte reale del numero complesso.

Abbiamo, inoltre, a disposizione tutta una serie di operazioni matematiche che accettano, oltre che argomenti di tipo Complex, anche argomenti numerici preesistenti come Double, Integer, etc., etc.

La struttura ci mette, infine, a disposizione tre attributi statici che forniscono il prototipo dell’unità, dell’unità immaginaria e dello zero.

Un esempio pratico di utilizzo della struttura Complex è il calcolo delle soluzioni di un’equazione di secondo grado nella forma:

Il progetto allegato al post è formato da una semplice windows WPF, un model che si occupa del calcolo delle soluzioni dell’equazione di secondo grado e un viewmodel che si occupa di collegare il model alla window.

Non analizzeremo il viewmodel concentrandoci sulla classe EquationModel che contiene la logica di calcolo.

 

1. Imports System.Numerics
2. Namespace Model
3.     Public Enum EquationType
4.         Undefined
5.         FirstDegree
6.         SecondDegree
7.     End Enum
8.  
9.     Public Class EquationModel
10.         Public Property A As Double
11.         Public Property B As Double
12.         Public Property C As Double
13.  
14.         Public ReadOnly Property Delta As Double
15.             Get
16.                 Return (Math.Pow(B, 2) - 4 * A * C)
17.             End Get
18.         End Property
19.  
20.         Public ReadOnly Property Type As EquationType
21.             Get
22.                 If A = 0 Then
23.                     If B = 0 Then
24.                         Return EquationType.Undefined
25.                     Else
26.                         Return EquationType.FirstDegree
27.                     End If
28.                 Else
29.                     Return EquationType.SecondDegree
30.                 End If
31.             End Get
32.         End Property
33.  
34.         Public ReadOnly Property X1 As Complex?
35.             Get
36.                 Dim x As Complex?
37.                 Dim y As Complex?
38.                 CalculateSolutions(x, y)
39.                 Return x
40.             End Get
41.         End Property
42.  
43.         Public ReadOnly Property X2 As Complex?
44.             Get
45.                 Dim x As Complex?
46.                 Dim y As Complex?
47.                 CalculateSolutions(x, y)
48.                 Return y
49.             End Get
50.         End Property
51.  
52.         Private Sub CalculateSolutions(ByRef x1 As Complex?, ByRef x2 As Complex?)
53.             x1 = Nothing
54.             x2 = Nothing
55.             If A = 0 Then
56.                 If B <> 0 Then
57.                     x1 = -C / B
58.                     x2 = x1
59.                 End If
60.             Else
61.                 x1 = (-B + Complex.Sqrt(Delta)) / (2 * A)
62.                 x2 = (-B - Complex.Sqrt(Delta)) / (2 * A)
63.             End If
64.         End Sub
65.     End Class
66. End Namespace

La classe espone i tre coefficienti dell’equazione (A, B e C) e alcune proprietà calcolate:

• Delta : la quantità delta che viene utilizzata nel calcolo delle soluzioni;
• Type : tipo effettivo dell’equazione (non definita, di primo grado, di secondo grado);
• X1, X2 : soluzioni dell’equazione. Queste proprietà sono di tipo Complex? poichè non è detto che l’equazione abbia soluzioni (ad esempio A=0, B=0 e C=1 non ha soluzioni).

Il metodo privato CalculateSolutions() è il metodo utilizzato per il calcolo effettivo delle soluzioni. All’interno di questo metodo possiamo osservare l’utilizzo del metodo Sqrt() della struttura Complex per il calcolo della radice quadrata.

Il diagramma delle classi complessivo è il seguente:

L’applicazione WPF riportata in allegato ha la semplice interfaccia:

Da notare che la visualizzazione delle soluzioni (di fatto dei Complex?) è eseguita grazie al metodo di estensione:

1. <Extension()>
2. Public Function Format(ByVal c As Complex?) As String
3.     Dim retStrBuild = New StringBuilder
4.     If c.HasValue Then
5.         If c.Value.Real = 0 Then
6.             If c.Value.Imaginary = 0 Then
7.                 retStrBuild.Append("0")
8.             Else
9.                 retStrBuild.AppendFormat("{0:F4} i", c.Value.Imaginary)
10.             End If
11.         Else
12.             retStrBuild.AppendFormat("{0:F4}", c.Value.Real)
13.             If c.Value.Imaginary > 0 Then
14.                 retStrBuild.AppendFormat(" + {0:F4} i", c.Value.Imaginary)
15.             ElseIf c.Value.Imaginary < 0 Then
16.                 retStrBuild.AppendFormat(" - {0:F4} i", Math.Abs(c.Value.Imaginary))
17.             End If
18.         End If
19.     Else
20.         retStrBuild.Append("-")
21.     End If
22.     Return retStrBuild.ToString()
23. End Function

Il codice completo della solution è scaricabile dal seguente link:

 

Technorati Tags: System.Numerics,Complex,Visual Studio 2010,Framework 4.0,VB.NET