VB.NET: Istanziare oggetti generics tramite Reflection

Istanziare oggetti utilizzando la reflection è quanto mai semplice.

Supponiamo di avere una nostra classe Entita:

1. Public Class Entita
2.     Public Sub New()
3.  
4.     End Sub
5.  
6.     Public Sub New(ByVal id As Int32)
7.         Me.ID = id
8.     End Sub
9.  
10.     Public Property ID As Int32
11.  
12. End Class

Normalmente un istanza di classe Entita si ottiene semplicemente:

1. Dim miaEntita = New Entita()

Se, invece, vogliamo eseguire la stessa operazione utilizzando reflection abbiamo:

1. ' Recupero il tipo della classe da istanziare
2. Dim tipoEntita = Type.GetType("Entita")
3. If tipoEntita IsNot Nothing Then
4.     ' creo l'entità utilizzando il costruttore di default
5.     Dim miaEntita = Activator.CreateInstance(tipoEntita)
6.     ' creo l'entità utilizzando il costruttore che prevede l'id
7.     Dim miaEntita2 = Activator.CreateInstance(tipoEntita, New Object() {3})
8. End If

Il nome del tipo da creare utilizzando la Reflection deve essere tale che la classe sia “visibile” dal nostro applicativo.

Quindi se, ad esempio, stiamo istanziando un tipo presente in un assembly esterno dovremmo utilizzare la notazione:

Namespace.Tipo, Assembly

Il risultato del metodo CreateInstance della classe Activator è, però, un Object al cui interno, però, c’è effettivamente un oggetto di classe Entita. Per poter richiamare i metodi dello stesso siamo costretti ad utilizzare il late binding o ancora una volta la Reflection.

In ogni caso il meccanismo è abbastanza semplice. E se, invece, abbiamo un tipo generico come facciamo a dire quali sono i tipi che lo rendono istanziabile?

Facciamo un esempio. Immaginiamo di avere la classe:

1. Public Class EntitaGenerica(Of TId)
2.     Public Sub New()
3.  
4.     End Sub
5.  
6.     Public Sub New(ByVal id As TId)
7.         Me.ID = id
8.     End Sub
9.  
10.     Public Property ID As TId
11. End Class

che potrebbe rappresentazare una classe il cui tipo di identificativo può cambiare.

In questo, per eseguire l’equivalente dell’istruzione:

1. Dim miaEntita = New EntitaGenerica(Of Int32)()

utilizzando la Reflection, non possiamo utilizzare il codice visto in precedenza ma dobbiamo preventivamente recuperare il tipo generico utilizzando il metodo MakeGenericType della classe Type:

1. Dim tipoEntitaGenerica = GetType(EntitaGenerica(Of ))
2. Dim tipoId = GetType(Int32)
3. Dim tipoEntitaIntera = tipoEntitaGenerica.MakeGenericType({tipoId})
4. Dim entita = Activator.CreateInstance(tipoEntitaIntera)

I passi da eseguire, quindi sono:

1. Recuperare il tipo del generico da istanziare (nel nostro caso EntitaGenerica(Of ):
   
   
   1. Dim tipoEntitaGenerica = GetType(EntitaGenerica(Of ))
   
   
2. Recuperare il tipo o i tipi che saranno gli argomenti del generics (nel nostro caso Int32):
   
   
   1. Dim tipoId = GetType(Int32)
   
   
   
3. Creare il tipo rappresentato dal generico in cui abbiamo definito gli argomenti variabili (nel nostro caso EntitaGenerica(Of Int32):
   
   
   1. Dim tipoEntitaIntera = tipoEntitaGenerica.MakeGenericType({tipoId})
   
   
   
4. Utilizzare la classe Activator su quest’ultimo tipo che è, in definitiva il tipo da noi desiderato:
   
   
   1. Dim entita = Activator.CreateInstance(tipoEntitaIntera)

 

Il meccanismo è del tutto analogo per quelle classi generiche che hanno più argomenti. Per esemplificare il discorso supponiamo di voler creare una Tupla con un Int32, una String e un Boolean:

1. Dim tipoTuplaGenerica = GetType(Tuple(Of ,,))
2. Dim arrayTipoParametri = {GetType(Int32),
3.                           GetType(String),
4.                           GetType(Boolean)}
5. Dim tipoTuplaReale = tipoTuplaGenerica.MakeGenericType(arrayTipoParametri)
6.  
7. Dim tupla = Activator.CreateInstance(tipoTuplaReale,
8.                                      New Object() {1, "Pippo", True})

In questo esempio i parametri di tipo del generico (la classe Tuple(Of T1,T2,T3)) sono addirittura tre e, non esistendo il costruttore di default, siamo costretti a richiamare il CreateInstance dell’Activator con un array di Object.

Technorati Tag: generics,reflection,activator,typeconverter,gettype,vb.net,makegenerictype