Passa ai contenuti principali

Gli enumeratori e Visual Basic

Una delle novità presentate alla PDC2010 riguarda le specifiche di linguaggio per Visual Basic che permettono di implementare gli iteratori.

Per chi sviluppa in C#, gli iteratori sono presenti fin dalla versione 2.0 del Framework mentre per gli sviluppatori VB tali oggetti non esistevano.

Partiamo con la definizione di iteratore: un iteratore è oggetto che permette di scandire il contenuto di una lista.

La parola chiave che si utilizza per definire il “ritorno” di uno degli oggetti della lista è yield che viene anteposta all’istanza da restuire. L’insieme degli yield deve essere posto all’interno di un metodo (di tipo function) che restituisca IEnumerator, IEnumerator(Of T), IEnumerable o IEnumerable(Of T).

Facciamo subito un esempio molto semplice: vogliamo creare un iteratore che dia la possibilità di iterare sui primi 5 numeri interi:

  1. Sub Main()
  2.     For Each intero In Get5Numeri()
  3.         Console.WriteLine(intero)
  4.     Next
  5. End Sub
  6.  
  7. Private Iterator Function Get5Numeri() As IEnumerable(Of Integer)
  8.     Yield 1
  9.     Yield 2
  10.     Yield 3
  11.     Yield 4
  12.     Yield 5
  13. End Function

Se proviamo ad eseguire passo passo il codice scritto in precedenza possiamo osservare che:

  • il For Each richiama l’iteratore Get5Numeri ma non entra all’interno del metodo;
  • ogni volta che si esegue una iterazione del ciclo possiamo osservare che il punto di esecuzione passa da uno yield al successivo:

Flusso di esecuzione

La parola chiave yield, quindi, viene richiamata ogni volta che l’iteratore “fa un passo avanti”.

Ovviamente, possiamo utilizzare la parola chiave yield in un contesto dinamico come, ad esempio, questo iteratore per la tabellina del due:

  1. Sub Main()
  2.     For Each intero In MultipliDiDue(10)
  3.         Console.WriteLine(intero)
  4.     Next
  5. End Sub
  6.  
  7. Private Iterator Function MultipliDiDue(ByVal n As Integer) As IEnumerable(Of Integer)
  8.     For index = 0 To n
  9.         Yield 2 * index
  10.     Next
  11. End Function

L’utilizzo degli iteratori ci permette di realizzare classi liste in maniera molto semplice ed efficiente.

Supponiamo di voler descrivere una classe di alunni e di fornire delle funzionalità che ci permettono di scorrere tutti gli alunni presenti in essa e, magari, tutti i maschi e tutte le femmine.

Utilizzando gli iteratori possiamo scrivere:

  1. Public Class Classe
  2.     Implements IEnumerable
  3.  
  4.     Private _Alunni As New List(Of Alunno)
  5.  
  6.     Public Iterator Function GetEnumerator() As System.Collections.IEnumerator Implements System.Collections.IEnumerable.GetEnumerator
  7.         For Each alunno In _Alunni
  8.             Yield alunno
  9.         Next
  10.     End Function
  11.  
  12.     Private Iterator Function AlunniPerSesso(ByVal sesso As Sesso) As IEnumerable
  13.         For Each alunno In _Alunni
  14.             If alunno.Sesso = sesso Then
  15.                 Yield alunno
  16.             End If
  17.         Next
  18.     End Function
  19.  
  20.     Public ReadOnly Property Maschi As IEnumerable
  21.         Get
  22.             Return AlunniPerSesso(Sesso.Maschio)
  23.         End Get
  24.     End Property
  25.  
  26.     Public ReadOnly Property Femmine As IEnumerable
  27.         Get
  28.             Return AlunniPerSesso(Sesso.Femmina)
  29.         End Get
  30.     End Property
  31.  
  32.     Public Sub AggiungiAlunno(ByVal nome As String)
  33.         _Alunni.Add(New Alunno() With {.Nome = nome, .Sesso = Sesso.Maschio})
  34.     End Sub
  35.  
  36.     Public Sub AggiungiAlunna(ByVal nome As String)
  37.         _Alunni.Add(New Alunno() With {.Nome = nome, .Sesso = Sesso.Femmina})
  38.     End Sub
  39. End Class
  40.  
  41. Public Class Alunno
  42.     Property Nome As String
  43.     Property Sesso As Sesso
  44. End Class
  45.  
  46. Public Enum Sesso
  47.     Maschio
  48.     Femmina
  49. End Enum

Con questa classe possiamo scrivere:

  1. Sub Main()
  2.     Dim terzaC = New ClasseSenzaIteratore()
  3.     terzaC.AggiungiAlunno("Marco")
  4.     terzaC.AggiungiAlunno("Filippo")
  5.     terzaC.AggiungiAlunna("Marta")
  6.     terzaC.AggiungiAlunna("Sara")
  7.     terzaC.AggiungiAlunno("Antonio")
  8.     terzaC.AggiungiAlunna("Carmela")
  9.  
  10.     For Each alunno As Alunno In terzaC
  11.         Console.WriteLine(alunno.Nome)
  12.     Next
  13.     Console.WriteLine()
  14.     For Each alunno As Alunno In terzaC.Maschi
  15.         Console.WriteLine(alunno.Nome)
  16.     Next
  17.     Console.WriteLine()
  18.     For Each alunno As Alunno In terzaC.Femmine
  19.         Console.WriteLine(alunno.Nome)
  20.     Next
  21.  
  22.     Console.ReadLine()
  23. End Sub

Ovviamente una classe analoga sarebbe realizabile anche senza gli iteratori ma dovremmo ricorrere ad artifizi come creare liste di appoggio e sfruttare l’iteratore delle stesse:

  1. Public Class ClasseSenzaIteratore
  2.     Implements IEnumerable
  3.  
  4.     Private _Alunni As New List(Of Alunno)
  5.  
  6.     Public Function GetEnumerator() As System.Collections.IEnumerator Implements System.Collections.IEnumerable.GetEnumerator
  7.         Return _Alunni.GetEnumerator()
  8.     End Function
  9.  
  10.     Private Function AlunniPerSesso(ByVal sesso As Sesso) As IEnumerable
  11.         Dim tmpList = From a In _Alunni
  12.                       Where a.Sesso = sesso
  13.                       Select a
  14.  
  15.         Return tmpList
  16.     End Function
  17.  
  18.     Public ReadOnly Property Maschi As IEnumerable
  19.         Get
  20.             Return AlunniPerSesso(Sesso.Maschio)
  21.         End Get
  22.     End Property
  23.  
  24.     Public ReadOnly Property Femmine As IEnumerable
  25.         Get
  26.             Return AlunniPerSesso(Sesso.Femmina)
  27.         End Get
  28.     End Property
  29.  
  30.     Public Sub AggiungiAlunno(ByVal nome As String)
  31.         _Alunni.Add(New Alunno() With {.Nome = nome, .Sesso = Sesso.Maschio})
  32.     End Sub
  33.  
  34.     Public Sub AggiungiAlunna(ByVal nome As String)
  35.         _Alunni.Add(New Alunno() With {.Nome = nome, .Sesso = Sesso.Femmina})
  36.     End Sub
  37.  
  38. End Class

Il codice è meno pulito e, abbiamo la necessità di liste d’appoggio.

Un metodo che implementa IEnumerable può anche non essere direttamente marcato con la parola chiave Iterator, purchè restituisca il risultato di un metodo marcato con Iterator:

  1. Private Function GetNumeri(ByVal min As Integer, ByVal max As Integer) As IEnumerable
  2.     If min < 0 Then Throw New Exception("Min < 0")
  3.     If min > max Then Throw New Exception("Min > max")
  4.  
  5.     Dim GetNumeriAlVolo = Iterator Function() As IEnumerable
  6.                               For index = min To max
  7.                                   Yield index
  8.                               Next
  9.                           End Function
  10.  
  11.     Return GetNumeriAlVolo()
  12. End Function

In questo caso, utilizziamo addirittura un anonymous iterator.

Le potenzialità del linguaggio, quindi, aumentano a dismisura in termini di efficienza, compattezza del codice e manutenibilità.

Per poter utilizzare Iterator e Yield nel proprio codice è necessario scaricare ed installare Async CTP al cui interno, oltre che il framework Async, troviamo la definizione delle nuove parole chiave.

E’ possibile scaricare Async CTP al seguente link, mentre la home page di Async CTP è raggiungibile al seguente link.

Ovviamente le nuove features sono disponibili per Visual Studio 2010 e framework 4.0.

 

Tag di Technorati: ,,,

Commenti

Post popolari in questo blog

VB.NET: Convertire un file DOC in RTF e PDF con office interop

In questo post vorrei proporvi del codice per poter convertire un file .doc in un file .rtf oppure .pdf utilizzando le API di interoperabilità di Office.Creeremo una classe, DocConverter, che esporrà le due funzionalità sopra citate.Cominciamo con il prevedere un attributo privato della classe che rappresenterà l’applicazione Word che utilizzeremo per la conversione. Creeremo l’istanza dell’attributo privato all’interno del costruttore della classe:PublicSubNew()
IfNot CreateWordApp() Then
ThrowNew ApplicationException("Assembly di interoperabilità con Office non trovato!")
EndIf
EndSub
Private _wordApp As Word.ApplicationClass
ProtectedFunction CreateWordApp() AsBoolean
Dim retval = True
Try
_wordApp = New Word.ApplicationClass()
_wordApp.Visible = False
Catch ex As System.Exception
_wordApp = Nothing
retval = False
EndTry
Return retval
EndFunction

La conversione del file doc sarà effettuata aprendo il file stesso ed eseguendo un’operazione di SaveAs:

Pr…

VB.NET for Dummies: Gli Eventi

Vorrei iniziare con questo post una serie dedicata ad aspetti di VB.NET di base che possono essere utile a coloro che si avvicinano al mondo .NET e che, in genere, non vengono trattati a livello base.La serie di post non ha la pretesa di essere assolutamente esaustivi sugli argomenti che tratteròIn questo primo post parleremo degli eventi.Cosa sono e a cosa servonoUn evento è la “notifica” dell’accadimento di qualcosa.Quando, ad esempio, premiamo un bottone della finestra di un’applicazione, dietro le quinte, il bottone stesso “notifica” al mondo circostante che qualcuno, in quell’istante, lo ha premuto.Sta, poi, al mondo circostante preoccuparsi di “intercettare” l’evento stesso per gestirlo (tramite un gestore di evento).Attenzione a non confondere la pressione del tasto con la “notifica” della pressione del tasto: l’evento è la “notifica” dell’accadimento, non l’accadimento stesso.Ma a cosa serve tutto ciò?Utilizzare gli eventi è un modo per disaccoppiare due o più attori del nostr…

Creare uno shortcut con VB.NET

Prendendo spunto da un post comparso sul forum MSDN vorrei proporvi un tip su come creare uno shortcut utilizzando VB.NET.Per poter creare uno shortcut possiamo procedere in due modi: o ci studiamo la struttura del file .lnk e scriviamo una classe che è in grado di ricreare tale struttura oppure utilizziamo Windows Scripting Host.La prima soluzione è percorribile ma laboriosa perchè la struttura di un file lnk non è banale. Chi fosse interessato a vedere come è composto, internamente, un file lnk può scaricare la seguente reference guide (link).Io vorrei proporvi la seconda strada e realizzerò una classe che incapsula l’utilizzo di Windows Scripting Host.L’object model di Windows Scripting Host è contenuto nella dll IWshRuntimeLibrary che può essere referenziata, nel nostro progetto, utilizzando il tab COM della finestra di aggiunta delle reference:Tra gli oggetti che troviamo all’interno della libreria utilizzeremo la classe WshShell e la classe WshShortcut.La prima delle due rappres…