Passa ai contenuti principali

VB for Dummies: Tipi anonimi e la parola chiave Key

I tipi anonimi (anonymous types) sono stati introdotti con il framework 3.5.

Sostanzialmente si tratta di oggetti istanziati “al volo” senza definirle esplicitamente il tipo a cui appartengono con il costrutto Class…End Class.

Tutti gli esempi riportati in questo post sono stati testati e realizzati con Visual Studio 2010 e .NET Framework 4.0. La maggior parte di quello che diremo sarà, in ogni caso, valido anche per il framework 3.5.

Un esempio di anonymous type è il seguente:

  1. Dim obj1 = New With {.Username = "verdi.giuseppe",
  2.                      .Cognome = "Verdi",
  3.                      .Nome = "Giuseppe"}

Otteniamo un oggetto che contiene tre proprietà (Username, Cognome e Nome) di tipo stringa ma non è un’istanza di una classe ben precisa:

image

In realtà, il compilatore costruisce per noi una classe che non vediamo e che viene utilizzata ogni qual volta istanziamo un anonymous type dello stesso tipo (cioè un oggetto che ha tre proprietà Username, Cognome e Nome).

Per verificare quello che abbiamo detto, scriviamo il seguente codice:

  1. Sub Main()
  2.     Dim obj1 = New With {.Username = "verdi.giuseppe",
  3.                          .Cognome = "Verdi",
  4.                          .Nome = "Giuseppe"}
  5.  
  6.     Dim obj2 = New With {.Username = "bianchi.carlo",
  7.                          .Cognome = "Bianchi",
  8.                          .Nome = "Carlo"}
  9. End Sub

compiliamolo e apriamo il codice generato tramite Reflector:

image

Come possiamo vedere dalla precedente immagine, il compilatore crea, per noi, una classe (chiamata VB$AnonymousType_0, ma potrebbe chiamarsi in qualsiasi modo) che descrive esattamente l’anonymous type da noi creato.

Analizzando questa classe:

image

osserviamo che è marcata come classe generata dal compilatore (attributo CompilerGenerated).

Il compilatore è in grado di capire che, pur avendo noi utilizzato due anonymous type distinti (obj1 e obj2), questi in realtà sono rappresentabili con la medesima classe e, perciò, non crea due classi distinte ma riutilizza la stessa.

Altra cosa che ci salta all’occhio è che la classe “anonima” è generata come generics (i tipi generici saranno oggetto di un altro post in futuro). Questo ci fa dedurre che il compilatore potrebbe essere in grado di riutilizzare la medesima classe anche per quei tipi anonimi che hanno proprietà con stesso nome ma tipo differente.

Proviamo a scrivere:

  1. Dim obj3 = New With {.Username = 7,
  2.                      .Cognome = "Bianchi",
  3.                      .Nome = "Carlo"}

Se compiliamo il progetto ed apriamo l’assembly generato, possiamo osservare che non viene creata un’altra classe “anonima” ma viene riutilizzata (come giustamente dovrebbe accadere) la precedente.

image

I tipi anonimi derivano, come possiamo vedere anche in una delle figure precedenti, dalla classe Object e non ridefiniscono i metodi GetHashCode e Equals.

Il metodo GetHashCode permette di ottenere un intero che identifica l’oggetto. Purtroppo l’implementazione di base (quella della classe object) non garantisce che i valori restituiti siano univoci per oggetti diversi. Questo inficia, di fatto, le operazioni di confronto che utilizzano l’hash.

In maniera analoga l’implementazione di base del metodo Equals, per i reference types (come di fatto sono i tipi anonimi), supporta l’uguaglianza dei riferimenti. Questa significa che due istanze differenti tipi anonimi esattamente uguali per contenuti sono differenti per il metodo Equals di Object.

  1. Public Sub TestObjectEquals()
  2.     Dim obj1 = New With {.Username = "verdi.giuseppe",
  3.                          .Cognome = "Verdi",
  4.                          .Nome = "Giuseppe"}
  5.     Dim obj2 = New With {.Username = "verdi.giuseppe",
  6.                          .Cognome = "Verdi",
  7.                          .Nome = "Giuseppe"}
  8.  
  9.     Dim eq = obj1.Equals(obj2) ' FALSE
  10. End Sub

In una classe da noi realizzata possiamo implementare l’override del metodo Equals ma in un tipo anonimo che si fa?

In questo caso interviene la parola chiave Key. Questa permette di definire, in un tipo anonimo, quelle proprietà che sono considerate come “chiavi” per l’oggetto.

Un esempio potrebbe essere:

  1. Dim obj1 = New With {Key .Username = "verdi.giuseppe",
  2.                      .Cognome = "Verdi",
  3.                      .Nome = "Giuseppe"}

Utilizzare la parola chiave Key produce alcuni risultati interessanti:

  1. la proprietà “marcata” con la Key è in sola lettura;
  2. il metodo GetHashCode utilizza la proprietà per il calcolo;
  3. il metodo Equals viene ridefinito dal compilatore basandosi sulla proprietà stessa.

Compiliamo la definizione di prima e otteniamo:

image

Rispetto al precedente caso abbiamo che la classe implementa l’interfaccia IEquatable, i metodi Equals e GetHashCode e la proprietà Username è, effettivamente, di sola lettura.

Se analizziamo l’implementazione del metodo Equals otteniamo:

  1. <DebuggerNonUserCode> _
  2. Public Function Equals(ByVal val As VB$AnonymousType_0(Of T0, T1, T2)) As Boolean
  3.         Implements IEquatable(Of VB$AnonymousType_0(Of T0, T1, T2)).Equals
  4.     If (val Is Nothing) Then
  5.         Return False
  6.     End If
  7.     Dim e_ As VB$AnonymousType_0(Of T0, T1, T2) = val
  8.     If (Me.$Username Is Nothing) Then
  9.         If (Not e_.$Username Is Nothing) Then
  10.             Return False
  11.         End If
  12.     ElseIf (e_.$Username Is Nothing) Then
  13.         Return False
  14.     End If
  15.     If (((Not Me.$Username Is Nothing) AndAlso
  16.             (Not e_.$Username Is Nothing)) AndAlso
  17.             Not Me.$Username.Equals(e_.$Username)) Then
  18.         Return False
  19.     End If
  20.     e_ = Nothing
  21.     Return True
  22. End Function

Il metodo, effettivamente, utilizza Username come chiave per verificare che due oggetti istanza del tipo anonimo siano o meno uguali.

Grazie alla parola chiave Key possiamo scrivere:

  1. Public Sub TestObjectEquals()
  2.     Dim obj1 = New With {Key .Username = "verdi.giuseppe",
  3.                          .Cognome = "Bianchi",
  4.                          .Nome = "Carlo"}
  5.     Dim obj2 = New With {Key .Username = "verdi.giuseppe",
  6.                          .Cognome = "Verdi",
  7.                          .Nome = "Giuseppe"}
  8.  
  9.     Dim eq = obj1.Equals(obj2) ' True
  10. End Sub

Ovviamente la parola Key può essere applicata a più proprietà contemporaneamente:

  1. Dim obj1 = New With {Key .Username = "verdi.giuseppe",
  2.                      Key .Cognome = "Verdi",
  3.                      Key .Nome = "Giuseppe"}

Il compilatore, di conseguenza, ridefinirà GetHashCode e Equals in modo da utilizzare tutte e tre le proprietà (definite, a questo punto, come di sola lettura).

I tipi anonimi, dunque, possono rappresentare un ottimo strumento da utilizzare, all’interno dei nostri metodi per mantanere dati locali che debbono subire confronti o finire in strutture dove l’hash è fondamentale. Non sono assolutamente da utilizzare per lo scambio dei dati in cui è opportuno costruire una nostra classe “vecchio stampo”.

Commenti

Post popolari in questo blog

VB.NET: Convertire un file DOC in RTF e PDF con office interop

In questo post vorrei proporvi del codice per poter convertire un file .doc in un file .rtf oppure .pdf utilizzando le API di interoperabilità di Office.Creeremo una classe, DocConverter, che esporrà le due funzionalità sopra citate.Cominciamo con il prevedere un attributo privato della classe che rappresenterà l’applicazione Word che utilizzeremo per la conversione. Creeremo l’istanza dell’attributo privato all’interno del costruttore della classe:PublicSubNew()
IfNot CreateWordApp() Then
ThrowNew ApplicationException("Assembly di interoperabilità con Office non trovato!")
EndIf
EndSub
Private _wordApp As Word.ApplicationClass
ProtectedFunction CreateWordApp() AsBoolean
Dim retval = True
Try
_wordApp = New Word.ApplicationClass()
_wordApp.Visible = False
Catch ex As System.Exception
_wordApp = Nothing
retval = False
EndTry
Return retval
EndFunction

La conversione del file doc sarà effettuata aprendo il file stesso ed eseguendo un’operazione di SaveAs:

Pr…

Creare uno shortcut con VB.NET

Prendendo spunto da un post comparso sul forum MSDN vorrei proporvi un tip su come creare uno shortcut utilizzando VB.NET.Per poter creare uno shortcut possiamo procedere in due modi: o ci studiamo la struttura del file .lnk e scriviamo una classe che è in grado di ricreare tale struttura oppure utilizziamo Windows Scripting Host.La prima soluzione è percorribile ma laboriosa perchè la struttura di un file lnk non è banale. Chi fosse interessato a vedere come è composto, internamente, un file lnk può scaricare la seguente reference guide (link).Io vorrei proporvi la seconda strada e realizzerò una classe che incapsula l’utilizzo di Windows Scripting Host.L’object model di Windows Scripting Host è contenuto nella dll IWshRuntimeLibrary che può essere referenziata, nel nostro progetto, utilizzando il tab COM della finestra di aggiunta delle reference:Tra gli oggetti che troviamo all’interno della libreria utilizzeremo la classe WshShell e la classe WshShortcut.La prima delle due rappres…

VB.NET for Dummies: Gli Eventi

Vorrei iniziare con questo post una serie dedicata ad aspetti di VB.NET di base che possono essere utile a coloro che si avvicinano al mondo .NET e che, in genere, non vengono trattati a livello base.La serie di post non ha la pretesa di essere assolutamente esaustivi sugli argomenti che tratteròIn questo primo post parleremo degli eventi.Cosa sono e a cosa servonoUn evento è la “notifica” dell’accadimento di qualcosa.Quando, ad esempio, premiamo un bottone della finestra di un’applicazione, dietro le quinte, il bottone stesso “notifica” al mondo circostante che qualcuno, in quell’istante, lo ha premuto.Sta, poi, al mondo circostante preoccuparsi di “intercettare” l’evento stesso per gestirlo (tramite un gestore di evento).Attenzione a non confondere la pressione del tasto con la “notifica” della pressione del tasto: l’evento è la “notifica” dell’accadimento, non l’accadimento stesso.Ma a cosa serve tutto ciò?Utilizzare gli eventi è un modo per disaccoppiare due o più attori del nostr…