martedì 22 dicembre 2009

VS2010 – VB.NET : Collection Initializers

Altra nuova funzionalità di linguaggio inserita nella versione VB.NET 10 è la possibilità di definire, istanziare e riempire delle collezioni di oggetti in un unica istruzione.

Nelle versioni precedenti di VB.NET avevamo bisogno di scrivere:

  1. Dim list = New List(Of Integer)
  2. With list
  3.     .Add(1)
  4.     .Add(2)
  5.     .Add(3)
  6.     .
  7.     .
  8. End With

Nella versione 10 di VB.NET possiamo, invece, scrivere

  1. Dim list = New List(Of Integer) From
  2.             {1,2,3,.,.,.,.}

I valori passati dopo la clausola From possono anche essere delle variabili.

Ma come si comporta il compilatore quando utilizziamo la nuova sintassi?

Per verificare ciò, supponiamo di avere la seguente classe:

  1. Public Class CityRepository
  2.  
  3.     Public Function GetCity() As List(Of String)
  4.         Dim cityList = New List(Of String) From
  5.                         {"Roma",
  6.                          "Milano",
  7.                          "Napoli",
  8.                          "Genova",
  9.                          "Firenze",
  10.                          "Torino"}
  11.         Return cityList
  12.     End Function
  13. End Class

Se la compiliamo (inserendola in un progetto Visual Studio 2010) ed analizziamo l’assembly ottenuto utilizzando Reflector, otteniamo:

aa

Possiamo osservare che il compilatore, di fatto, fa esattamente quello che avremmo fatto noi, creando una variabile d’appoggio, riempiendola con i valori e restituendola al chiamante.

Non c’è traccia della nostra variabile cityList. In effetti il compilatore si accorge che la nostra cityList è, di fatto, una variabile di appoggio, mai utilizzata nella funzione e immediatamente restituita ed effettua una sorta di ottimizzazione del codice.

Se, infatti, modifichiamo la classe nel seguente modo:

  1. Public Class CityRepository
  2.  
  3.     Public Function GetCity() As List(Of String)
  4.         Dim cityList = New List(Of String) From
  5.                         {"Roma",
  6.                          "Milano",
  7.                          "Napoli",
  8.                          "Genova",
  9.                          "Firenze",
  10.                          "Torino"}
  11.         cityList.Add("Udine")
  12.         Return cityList
  13.     End Function
  14. End Class

Otteniamo:

dd

In questo caso, la variabile di appoggio introdotta dal compilatore viene “travasata” nella nostra variabile cityList subito dopo aver terminato di aggiungere gli elementi nella definizione iniziale.

Ciò che possiamo dedurre da queste osservazioni è che l’inizializzazione delle collezioni in un’unica riga non ottimizza le performance del codice ma migliora semplicemente la leggibilità (e già sarebbe sufficiente per utilizzarla) essendo assolutamente identica (a livello di codice compilato) della modalità con cui si creavano analoghe liste in VB.NET 9.

In realtà non è esattamente così e per verificarlo supponiamo di avere la seguente classe:

  1. Public Class IntegerRepository
  2.  
  3.     Public Function GetList() As List(Of Integer)
  4.         Dim lista As List(Of Integer) = Nothing
  5.         Try
  6.             lista = New List(Of Integer)
  7.             With lista
  8.                 .Add(2)
  9.                 .Add(4)
  10.                 .Add(System.Convert.ToInt32("a"))
  11.                 .Add(6)
  12.             End With
  13.         Catch ex As Exception
  14.  
  15.         End Try
  16.         Return lista
  17.     End Function
  18. End Class

Evidentemente, viene sollevata un’eccezione nel momento in cui si cerca di convertire la stringa “a” in un intero.

All’uscita della funzione, la lista è, però parzialmente valorizzata (sono infatti presenti i valori 2 e 4 ma non il 6).

dddd Se, ora modifichiamo la classe nel seguente modo:

  1. Public Class IntegerRepository
  2.  
  3.     Public Function GetList() As List(Of Integer)
  4.         Dim lista As List(Of Integer) = Nothing
  5.         Try
  6.             lista = New List(Of Integer) From
  7.                 {2, 4, 6, System.Convert.ToInt32("a")}
  8.         Catch ex As Exception
  9.  
  10.         End Try
  11.         Return lista
  12.     End Function
  13. End Class

Otteniamo che la lista di ritorno, nonostante sia sempre sollevata l’eccezione, è vuota (anzi non è neanche istanziata):

21-12-2009 14-02-56

In sostanza, utilizzando la nuova sintassi si realizza una sorta di “transazione” nell’operazione di definizione/istanziazione/riempimento della lista: o abbiamo la lista completa o niente.

Se mettiamo a confronto le due funzioni (rinominando GetListOld() quella creata nella vecchia maniera) possiamo analizzare il codice generato con Reflector e vedere che il compilatore si comporta in maniera completamente differente:

rerer

Utilizzare, quindi, i collection inizializers non è solo un modo per ottenere una sintassi compatta e più leggibile ma anche un modo per ottenere una transazione nell’operazione di creazione di una collection.

Prima di chiudere vorrei evidenziare il fatto che la collection inizializer si basa, come abbiamo visto, sull’utilizzo del metodo Add della collezione che stiamo istanziando. Questo significa che, se per caso, ridefiniamo tale metodo, tutto funziona in maniera automatica.

Ad esempio supponiamo di definire una classe Customer:

  1. Public Class Customer
  2.     Property ID As Integer
  3.     Property FirstName As String
  4.     Property LastName As String
  5. End Class

e di definire un metodo di estensione Add() che agisce su un’istanza dell’interfaccia IList e aggiunge un nuovo Customer:

  1. Imports System.Runtime.CompilerServices
  2.  
  3. Public Module Module1
  4.  
  5.     <Extension()>
  6.     Public Sub Add(ByVal list As IList(Of Customer),
  7.                     ByVal ID As Integer,
  8.                     ByVal FirstName As String,
  9.                     ByVal LastName As String)
  10.  
  11.         list.Add(New Customer With {.ID = ID,
  12.                                     .FirstName = FirstName,
  13.                                     .LastName = LastName})
  14.     End Sub
  15.  
  16. End Module

In questo modo creiamo una sorta di overload del metodo Add dell’interfaccia IList ed il compilatore è in grado di risolvere la seguente istruzione:

  1. Dim list As New List(Of Customer) From {
  2.             {1000, "Mario", "Rossi"},
  3.             {1100, "Giuseppe", "Verdi"},
  4.             {1200, "Carlo", "Bianchi"}}

restituendoci una lista di tre oggetti Customer:

sassa Se analizziamo il codice generato dal compilatore, ci rendiamo conto che viene, effettivamente, richiamato il nostro metodo di estensione:

hggh

Nessun commento: